FireMonkeyのMessageDialog | Object Pascalと僕と

FMX事始め

１．FMXでMessageDialogを表示する
２．TMsgDlgTypeに指定できる値はVCLと同じ
３．表示できるボタン
４．表示できないボタン
５．ダイアログ右上の閉じるボタンの挙動
６．まとめ
７．お願いとお断り

１．FMXでMessageDialogを表示する

いろいろな事情からFMXプラットフォームで、あるプログラムを書くことになった。使い慣れたVCLと違って、FireMonkeyはずっと以前に一度だけWAVファイルの再生プログラムを作った時触れたことがあるだけで、まともに触るのは今回が初めて。

最初にいちばん困ったのはユーザーへのメッセージの出し方。なんでかわからないけれど、普通にShowMessageすると、その直後、FMXプラットフォームでは、結構な頻度でエラーが発生する気が･･･。

だから、最初に書いたデータベース接続のプログラムは、極力ShowMessageを使わない方向で書いたんだけど、２作目のテキスト入力練習プログラムではそうも行かず、良い機会だと思ってShowMessageより見た目が華やかなMessageDialogの正しい使い方を調べてみた。

思った以上に情報が少ない気がしたので、学んだことを備忘録として、まとめておく。

まずは、ｉマーク付きのMessageDialogの出し方。

implementation

uses
  FMX.Platform, FMX.DialogService;

{$R *.fmx}

procedure TForm1.Button1Click(Sender: TObject);
var
  ASyncService:IFMXDialogServiceASync;
begin
  //mtConfirmationだとBeep音が鳴らないが、mtInformationだとBeep音が鳴る
  if TPlatformServices.Current.SupportsPlatformService (IFMXDialogServiceAsync,
    IInterface(ASyncService)) then
  begin
    TDialogService.MessageDialog('Do you know Delphi?',
      TMsgDlgType.mtInformation, [TMsgDlgBtn.mbOK], TMsgDlgBtn.mbOK, 0,
      procedure(const AResult: TModalResult)
      begin
        if AResult = mrOK then
        begin

        end;
      end);
  end;
end;

実行すると･･･

調べてわかったことは･･･

var
  ASyncService:IFMXDialogServiceASync;

･･･と宣言するためには、

uses
  FMX.Platform;

uses に FMX.Platform が必要で、さらに、サポートの有無を調査するif文の･･･

if TPlatformServices.Current.SupportsPlatformService (IFMXDialogServiceAsync,
    IInterface(ASyncService)) then

TPlatformServices も FMX.Platform を参照している。

で、本命の MessageDialog を表示するには、さらに･･･

uses
  FMX.Platform, FMX.DialogService;

uses に FMX.DialogService も追加しなければならない。

２．TMsgDlgTypeに指定できる値はVCLと同じ

上のユーザーへの情報提供（Info）に加えて、ユーザーに確認する場合は、

TMsgDlgType.mtConfirmation

ユーザーに警告。

TMsgDlgType.mtWarning

ユーザーにエラーを報告。

TMsgDlgType.mtError

mtCustomってのもあったけど･･･

TMsgDlgType.mtCustom

画像は、何も出てこなかった･･･。
キャプションもProject1（アプリケーション名）になってる･･･。

実質、「情報提供・確認・警告・エラー」の４つ型があり、これはVCLと変わらない。

３．表示できるボタン

ユーザーの応答が「OKボタン押し下げのみ」であれば、MessageDialogの最後の引数を別手続きにして、それを呼び出す形にすればいいのかと･･･

  private
    { private 宣言 }
    procedure MsgDlgProc(const AResult: TModalResult);

として、Shift＋Ctrl＋Cで手続きを作成。

procedure TForm1.MsgDlgProc(const AResult: TModalResult);
begin
  //何もしない手続き

end;

応答が「OK」のみの場合は、これを呼び出し。

procedure TForm1.Button2Click(Sender: TObject);
var
  ASyncService:IFMXDialogServiceASync;
begin
  if TPlatformServices.Current.SupportsPlatformService (IFMXDialogServiceAsync, IInterface(ASyncService)) then begin
    TDialogService.MessageDialog('Do you know Delphi?',
      TMsgDlgType.mtInformation, 
      [TMsgDlgBtn.mbOK], TMsgDlgBtn.mbOK, 0, MsgDlgProc);
  end;
end;

コードが短くなって、なんとなくすっきりした。

でも、「はい」・「いいえ」・「キャンセル」のようにボタンを複数表示するとそうもいかない。

procedure TForm1.Button3Click(Sender: TObject);
var
  ASyncService:IFMXDialogServiceASync;
begin
  if TPlatformServices.Current.SupportsPlatformService (IFMXDialogServiceAsync, IInterface(ASyncService)) then
  begin
    TDialogService.MessageDialog('Do you know Delphi?',
      TMsgDlgType.mtInformation, [TMsgDlgBtn.mbYes, TMsgDlgBtn.mbNo, TMsgDlgBtn.mbCancel], TMsgDlgBtn.mbYes, 0,
      procedure(const AResult: TModalResult)
      begin
        if AResult = mrYes then
        begin
          ShowMessage('Goooooooood!');
        end;
        if AResult = mrNo then
        begin
          ShowMessage('No Good!');
        end;
        if AResult = mrCancel then
        begin
          ShowMessage('Cancel');
        end;
      end);
  end;
end;

case文でもよいようだ。

procedure TForm1.Button3Click(Sender: TObject);
var
  ASyncService:IFMXDialogServiceASync;
begin
  if TPlatformServices.Current.SupportsPlatformService (IFMXDialogServiceAsync, IInterface(ASyncService)) then
  begin
    TDialogService.MessageDialog('Do you know Delphi?',
      TMsgDlgType.mtInformation, [TMsgDlgBtn.mbYes, TMsgDlgBtn.mbNo, TMsgDlgBtn.mbCancel], TMsgDlgBtn.mbYes, 0,
      procedure(const AResult: TModalResult)
      begin
        case AResult of
          mrYes:ShowMessage('Goooooooood!');
          mrNo:ShowMessage('No Good!');
          mrCancel:ShowMessage('Cancel');
        end;
      end);
  end;
end;

caseのリストが表す値は、case文内で一意、部分範囲またはリストの重複がなければ昇順とかリストの並びは関係ないようだ。また、このようによく使用されるボタン値は、セットになった定数として用意されていて、例えば上の場合は次のように指定できる。

TMsgDlgType.mtInformation, mbYesNoCancel, TMsgDlgBtn.mbYes, 0,

embarcaderoさんのWebサイトでは、TMsgDlgBtnは種類がたくさん紹介されていて、

定数	値	意味
`mrNone`	0	結果なし。ユーザーがフォームを終了するまでのデフォルト値として使用されます。
`mrOk`	idOK = 1	ユーザーは［OK］ボタンでフォームを終了しました。
`mrCancel`	idCancel = 2	ユーザーは［キャンセル］ボタンでフォームを終了しました。
`mrAbort`	idAbort = 3	ユーザーは［中止］ボタンでフォームを終了しました。
`mrRetry`	idRetry = 4	ユーザーは［再試行］ボタンでフォームを終了しました。
`mrIgnore`	idIgnore = 5	ユーザーは［無視］ボタンでフォームを終了しました。
`mrYes`	idYes = 6	ユーザーは［はい］ボタンでフォームを終了しました。
`mrNo`	idNo = 7	ユーザーは［いいえ］ボタンでフォームを終了しました。
`mrClose`	idClose = 8	ユーザーは［閉じる］ボタンでフォームを終了しました。
`mrHelp`	idHelp = 9	ユーザーは［ヘルプ］ボタンでフォームを終了しました。
`mrTryAgain`	idTryAgain = 10	ユーザーは［やり直し］ボタンでフォームを終了しました。
`mrContinue`	idContinue = 11	ユーザーは［続行］ボタンでフォームを終了しました。
`mrAll`	mrContinue + 1（12 つまり $C）	ユーザーは［すべて］ボタンでフォームを終了しました。
`mrNoToAll`	mrAll + 1（13 つまり $D）	ユーザーは［すべていいえ］ボタンでフォームを終了しました。
`mrYesToAll`	mrNoToAll + 1（14 つまり $E）	ユーザーは［すべてはい］ボタンでフォームを終了しました。

https://docwiki.embarcadero.com/Libraries/Sydney/ja/FMX.StdCtrls.TCustomButton.ModalResultより引用

さらに、セットになった定数が５つあるとのこと。

定数	意味
mbYesNoCancel	mbYes、mbNo、および mbCancel
mbYesAllNoAllCancel	mbYes、mbYesToAll、mbNo、mbNoToAll、および mbCancel
mbOKCancel	mbOK および mbCancel
mbAbortRetryIgnore	mbAbort、mbRetry、および mbIgnore
mbAbortIgnore	mbAbort、mbIgnore

https://docwiki.embarcadero.com/Libraries/Alexandria/ja/Vcl.Dialogs.TMsgDlgBtnより引用

４．表示できないボタン

僕のPCだけ、そうなのかもしれないけど。中には表示できないボタンが･･･。例えば、

procedure TForm1.Button7Click(Sender: TObject);
var
  ASyncService:IFMXDialogServiceASync;
begin
  if TPlatformServices.Current.SupportsPlatformService (IFMXDialogServiceAsync, IInterface(ASyncService)) then
  begin
    TDialogService.MessageDialog('Do you know Delphi?',
      TMsgDlgType.mtInformation,[TMsgDlgBtn.mbRetry],TMsgDlgBtn.mbRetry,0,
      procedure(const AResult: TModalResult)
      begin
        case AResult of
          mrOK:ShowMessage('OK!：了解');
          mrCancel:ShowMessage('Cancel：取消');
          mrAbort:ShowMessage('Abort：中止');
          mrRetry:ShowMessage('Retry：再試行');
          mrIgnore:ShowMessage('Ignore：無視');
          mrYes:ShowMessage('Yes：はい');
          mrNo:ShowMessage('No：いいえ');
          mrClose:ShowMessage('Close：閉じる');
          mrHelp:ShowMessage('Help：要援助');
          mrAll:ShowMessage('All：すべて');
          mrNoToAll:ShowMessage('NoToAll：すべていいえ');
          mrYesToAll:ShowMessage('YesToAll：すべてはい');
        else
          //ないと思うけど、
          ShowMessage(IntToStr(AResult));
        end;
      end);
  end;
end;

ボタンに mbRetry を指定しても、上の手続きを実行すると表示されたダイアログは･･･

で、OKを押し下げ。･･･ると

なんでかなー？

でも、次のように指定すると、

TMsgDlgType.mtInformation, [TMsgDlgBtn.mbCancel,TMsgDlgBtn.mbRetry]

で、「再試行(R)」を押し下げ。･･･ると

表示できる場合とできない場合があるらしい。つまり、これはダイアログに表示可能なボタンの設定（組み合わせ）を FMX の MessageDialog は内部的に持っているということ？それから、キャンセルボタンは必ず右側へ設置される？･･･から、ボタンの表示される順番もまた、決まっているという理解でいいのかな？･･･みたいな。

他にも、mbAbortRetryIgnore を指定して、デフォルトで選択状態にするボタンに mbRetry を指定しても･･･

TMsgDlgType.mtInformation, mbAbortRetryIgnore, TMsgDlgBtn.mbRetry, 0,

しかも、ダイアログ右上の「閉じる」ボタンが押せなくなってる（勝手にEnabled？がFalseに設定されてしまう）。これは、キャンセルがないから、閉じるボタンはその必要がないという意味に思えてくる･･･。だから、閉じるボタンの無効化も、VCLならその方法が紹介されているんだけど、FMXでの情報は見当たらないのか･･･

実は、この記事を書こうと思ったのは、この閉じるボタンをクリックした時の戻り値が何なのか、どんなに調べても（僕が調べた範囲では）見つけることが出来なかったので、実験してみた結果を記録しておこうと思ったことがきっかけというか、はじまり。

FMX の MessageDialog を設計した人の気持ちがだんだん、わかってきた！

５．ダイアログ右上の閉じるボタンの挙動

実験結果から見えてきたこと。それは MessageDialog の閉じるボタンは、そのクリックの可否がダイアログに表示するボタンの組み合わせによって、内部的に制御されているんじゃないか？ってこと。

まず、OKボタンのみの場合、

procedure TForm1.Button9Click(Sender: TObject);
var
  ASyncService:IFMXDialogServiceASync;
begin
  if TPlatformServices.Current.SupportsPlatformService (IFMXDialogServiceAsync, IInterface(ASyncService)) then
  begin
    TDialogService.MessageDialog('Do you know Delphi?',
      TMsgDlgType.mtInformation, [TMsgDlgBtn.mbOK], TMsgDlgBtn.mbOK, 0,
      procedure(const AResult: TModalResult)
      begin
        case AResult of
          mrOK:ShowMessage('OK!：了解');
          mrCancel:ShowMessage('Cancel：取消');
          mrAbort:ShowMessage('Abort：中止');
          mrRetry:ShowMessage('Retry：再試行');
          mrIgnore:ShowMessage('Ignore：無視');
          mrYes:ShowMessage('Yes：はい');
          mrNo:ShowMessage('No：いいえ');
          mrClose:ShowMessage('Close：閉じる');
          mrHelp:ShowMessage('Help：要援助');
          mrAll:ShowMessage('All：すべて');
          mrNoToAll:ShowMessage('NoToAll：すべていいえ');
          mrYesToAll:ShowMessage('YesToAll：すべてはい');
        else
          ShowMessage(IntToStr(AResult));
        end;
      end);
  end;
end;

ダイアログ右上の「×」をクリックすると表示されたのは･･･

つまり、OKをクリックするしか、選択肢がない（未来をプログラマ自身が選択した）のだから、閉じるボタンが押された時の戻り値もmrOKでよい･･･ということか！

次に、表示するボタンを「OK」と「キャンセル」にして、デフォルト選択ボタンは「キャンセル」に指定して、再度実行。

TMsgDlgType.mtInformation, [TMsgDlgBtn.mbOK, TMsgDlgBtn.mbCancel], TMsgDlgBtn.mbCancel, 0,

右上の「×」をクリックすると･･･

思った通り、mrCancel が設定されていた！　プログラマが「キャンセルという選択肢を未来に与えた」んだから、閉じるボタンが押された時は「キャンセル」と判断してよい･･･ということ？

デフォルト選択ボタンをOKに変えてみた･･･

TMsgDlgType.mtInformation, [TMsgDlgBtn.mbOK, TMsgDlgBtn.mbCancel], TMsgDlgBtn.mbOK, 0,

右上の「×」をクリックすると･･･

思った通りだ。

ボタンを「はい」・「いいえ」・「キャンセル」の３つにし、デフォルト選択を「はい」に指定して実験･･･

TMsgDlgType.mtInformation, [TMsgDlgBtn.mbYes, TMsgDlgBtn.mbNo, TMsgDlgBtn.mbCancel], TMsgDlgBtn.mbYes, 0,

右上の「×」をクリックすると･･･

やっぱり、mrCancelが戻り値に設定されている！

ならば、ボタンを「はい」・「いいえ」の２つだけにすると、閉じるボタンは使用不可になるはずだ･･･。だって、プログラマの意向として、未来に「キャンセル」という選択肢は与えられていないから！

実際に動かして確認。

TMsgDlgType.mtInformation, [TMsgDlgBtn.mbYes, TMsgDlgBtn.mbNo], TMsgDlgBtn.mbYes, 0,

僕の中に生まれた予測は、ここで「確信」に変わった！

これはVCLのMessageDlgでも同じなんだろうか？
今度、実験だ。

６．まとめ

（１）OKボタンのみ設置したダイアログでは、閉じるボタンクリックでmrOKが返る。
（２）ダイアログにキャンセルボタンを設置した場合は、閉じるボタンもクリック可能。
（３）キャンセルボタンがある場合、閉じるボタンクリックで返る値はmrCancelになる。
（４）キャンセルボタンがない場合、閉じるボタンはクリックできない。
（５）ボタンの組み合わせは内部的に不可もある（不可でもエラーにはならない）。

７．お願いとお断り

このサイトの内容を利用される場合は、自己責任でお願いします。ここに記載した内容を利用した結果、利用者および第三者に損害が発生したとしても、このサイトの管理者は一切責任を負えません。予め、ご了承ください。